Tag Archives: WENN

Ich führe gerade mit dem Rad einen Autokorso an. Es wird gehupt und geschrien – die Stimmung ist riesig!

Excelschulung. Wir üben die WENN-Funktion. Ich erkläre, dass man Text in Excel in Anführungszeichen setzen muss – manche Assistenten machen dies automatisch; andere nicht.

Meine Empfehlung: Immer per Hand die Anführungszeichen setzen:

Danach üben wir die bedingte Formatierung – auch eine Art „WENN“. Da die Teilnehmerinnen und Teilnehmer meinen Rat befolgen, tragen Sie den Text in Anführungszeichen ein:

Was passiert? – Nichts! Der Grund:

Excel wandelt den Text „Pandora Papers“ in „““Pandora Papers“““ um – Excel geht davon aus, dass die Anführungszeichen Teil des Suchtextes sind. Also raus damit!

Wer spät zu Bett geht und früh heraus muss, weiß, woher das Wort Morgengrauen kommt.

Zuerst hört sich die Frage ganz einfach an, aber dann kam ich ins Schleudern:

„Hallo Rene

zum Thema Datumsberechnungen hätte ich gleich eine Frage:

kann Excel auch Zeiträume erkennen, die sich überschneiden, aber unterschiedliche Anfangs- und Endzeiten haben?

Also zum Beispiel:

Mitarbeiter A arbeitet vom 01.05.2021 bis 31.08.2021

Mitarbeiter B arbeitet vom 01.06.2021 bis 15.09.2021

In welchem Zeitraum haben beide gearbeitet

Oder

Von Bis Thema
8:00 12:00 Nachdenken
11:30 12:30 Pause
12:30 15:00 Nix tun

Ich überlege. Und erweitere das Beispiel. Das Oktoberfest hätte in diesem Jahr vom 18. September bis 03. Oktober stattgefunden. Adelheid ist von 01.09. bis 30.09 in München; Basti vom 25.09. bis 25.10.; Christoph vom 27.09. bis 30.09.; Doris vom 10.09. bis 10.10.; Erich vom 01.09. bis 10.09. und Franziska vom 10.10. bis 20.10. Wie viele Tage hätten sie aufs Oktoberfest gehen können?

Im ersten Schritt habe ich das visualisiert:

Ich beginne mit Erich und Franziska: Wenn Ende < Beginn Oktoberfest, dann 0. Wenn Anfang > Ende Oktoberfest, dann 0:

=WENN(B33<$B$21;0)

Dann die umschließenden Bereiche:

=WENN(UND(B28>=$B$21;B29<=B22);B29-B28+1;0)

Und schließlich die überschneidenden Bereiche:

Wenn Anfang <= Anfang Oktoberfest und Ende <= Ende Oktoberfest, dann Ende – Anfang Oktoberfest:

=WENN(UND(B24<=$B$21;B25<=$B$22);B25-$B$21+1;0)

Analog die zweite Überschneidung:

Wenn Ende >= Ende Oktoberfest und Anfang >= Anfang Oktoberfest, dann Ende Oktoberfest – Anfang:

=WENN(UND(B27>=$B$22;B26>=$B$21);$B$22-B26+1;0)

Dabei fällt auf, dass die ersten beiden Fälle mit einbezogen werden – man muss sie explizit ausschließen, beispielsweise mit einem dritten Fall:

und Ende >= Anfang Oktoberfest, beziehungsweise: Anfang <= Ende Oktoberfest:

=WENN(UND(B24<=$B$21;B25<=$B$22;B25>=$B$21);B25-$B$21+1;0)

beziehungsweise:

=WENN(UND(B27>=$B$22;B26>=$B$21;B26<=$B$22);$B$22-B26+1;0)

so:

Ein Summieren der Varianten verbietet sich, da stets mit >= und <= gearbeitet wurde. So könnte ein Datumsbereich vom 18.09. bis 20.09. in zwei der sechs Kategorien fallen. Entweder man ändert einige der <=in < oder man baue den Baum auf:

  1. Fall: leere Menge
  2. Fall: ganzer Bereich
  3. Fall: Überschneidung
  1. Fall:
=WENN(ODER(B33<$B$21;B32>$B$22);0)

2. Fall a: Datumsbereich liegt im Oktoberfestzeitraum:

=WENN(ODER(B33<$B$21;B32>$B$22);0;WENN(UND(B32>=$B$21;B33<=$B$22);B33-B32+1;0))

2. Fall b: Oktoberfestzeitraum liegt im Datumsbereich:

=WENN(ODER(B31<$B$21;B30>$B$22);0;WENN(UND(B30>=$B$21;B31<=$B$22);B31-B30+1;WENN(UND($B$21>=B30;$B$22<=B31);$B$22-$B$21+1;0)))

Und schließlich die beiden Fälle Nummer 3:

=WENN(ODER(B25<$B$21;B24>$B$22);0;WENN(UND(B24>=$B$21;B25<=$B$22);B25-B24+1;WENN(UND($B$21>=B24;$B$22<=B25);$B$22-$B$21+1;WENN(UND(B24<=$B$21;B25<=$B$22);B25-$B$21+1;0))))

und:

=WENN(ODER(B27<$B$21;B26>$B$22);0;WENN(UND(B26>=$B$21;B27<=$B$22);B27-B26+1;WENN(UND($B$21>=B26;$B$22<=B27);$B$22-$B$21+1;WENN(UND(B26<=$B$21;B27<=$B$22);B27-$B$21+1;WENN(UND(B27>=$B$22;B26>=$B$21);$B$22-B26+1;0)))))

Natürlich hätte man die Bedingungen auch umdrehen können.

Natürlich hätte man den Bedingungsbaum auch anders aufbauen können:

  1. Fall: Anfang <= Oktoberfest Anfang? Ja:
    Fall a) Ende vor Oktoberfest Anfang?
    Fall b) Ende nach Oktoberfest Ende?
    Fall c) Ende zwischen Oktoberfest Anfang und Ende?
    […]

Die Teilnehmerinnen waren begeistert und erschöpft. Leider haben sie nur Excel 2016. Ich überlegte mir, ob man das Problem nicht mit den Matrixfunktionen SEQUENZ & co lösen kann. Die Antwort: Man kann:

Wir beginnen mit Adelheid. Im ersten Schritt werden alle Adelheid-Tage und Oktoberfesttage aufgelistet. Die Funktion SEQUENZ hilft hierbei:

=SEQUENZ(A6-A5+1;1;A5)

Nun kann man zählen, wie oft jeder Adelheid-Tag in der Oktoberfest-Tagesliste vorkommt – einmal oder kein Mal:

=ZÄHLENWENN($E$1#;C1)

Und diese Kolonne kann man summieren.

Oder in einer Formel:

=SUMME(ZÄHLENWENN($C$1#;SEQUENZ(A6-A5+1;1;A5)))

Geht das auch mit FILTER? Klar:

=FILTER(C1#;(C1#>=A5)*(C1#<=A6))

Oder in einer Formel:

=FILTER(SEQUENZ(A2-A1+1;1;A1);(SEQUENZ(A2-A1+1;1;A1)>=A5)*(SEQUENZ(A2-A1+1;1;A1)<=A6))

Ich bin sicher, dass es für dieses Problem noch weitere Lösungen gibt. Viel Spaß beim Knobeln.

Hallo Rene,
meine Lösungsvorschlag kommt mit einer einer einfachen Formel (ohne Matrixformel) aus.

Das Startdatum des Oktoberfest steht in B2
Das Enddatum des Oktoberfest steht in B3

Der erste Tag von Adele in München steht in B5
Der letzte Tag von Adele in München steht in B6

Dann berechnet folgende Formel die Überschneidung, also die Anzahl von Tagen die Adele auf das Oktoberfest gehen kann.

=ZEILEN(INDEX(A:A;B2):INDEX(A:A;B3) INDEX(A:A;B5):INDEX(A:A;B6))

Im Falle Adele 13 Tage.

Für die anderen Personen muss diese Formel nur entsprechend angepasst werden.
Gibt es keine Überschneidung wie bei Erich und Franziska gibt die Formel den Wert #NULL! aus.
Wichtig ist das Leerzeichen in der Mitte der Formel. Dadurch wird die Schnittmenge ermittelt.

Salü

Ernst

PS: Nachtrag:

Allerdings kann man durch eine kleine Änderung der Formel meines Lösungsvorschlages (aus Zeilen() mache Zeile() und gebe die Formel als Matrixformel ein) eine einspaltige Matrix erzeugen, in der die Datumswerte der Schnittmenge eingetragen sind.

Also

=ZEILEN(INDEX($A:$A;$B$2):INDEX($A:$A;$B$3) INDEX($A:$A;B5):INDEX($A:$A;B6))

Ergebnis = 13

{=ZEILE(INDEX($A:$A;$B$2):INDEX($A:$A;$B$3) INDEX($A:$A;B5):INDEX($A:$A;B6)) }

Ergebnis ( Zellen als kurzes Datum formatiert.):

18.09.2021
19.09.2021
20.09.2021
21.09.2021
22.09.2021
23.09.2021
24.09.2021
25.09.2021
26.09.2021
27.09.2021
28.09.2021
29.09.2021
30.09.2021

Danke Ernst – sehr clever!

Und schließlich hat Helmut Cantzler eine Lösung mit SUMMENPRODUKT gefunden:

=SUMMENPRODUKT((SEQUENZ($B$3-$B$2+1;;$B$2;1)<=B6)*(SEQUENZ($B$3-$B$2+1;;$B$2;1)>=B5))

Danke an Helmut – auch sehr clever!

Und schließlich kann man das Problem auch mit VBA lösen. Man muss zwei Bereiche (Range) definieren und die Schnittmenge (Application.Intersect) bestimmen:

    Dim xlBereich1 As Range
    Dim xlBereich2 As Range
    Dim xlSchnittmenge As Range
    With ThisWorkbook.Worksheets("Helmut")
        Set xlBereich1 = .Range(.Cells(Range("B2").Value2, 1), 
           .Cells(.Range("B3").Value2, 1))
        Set xlBereich2 = .Range(.Cells(Range("B5").Value2, 1), 
           .Cells(.Range("B6").Value2, 1))
    End With
    Set xlSchnittmenge = Application.Intersect(xlBereich1, xlBereich2)
    MsgBox xlSchnittmenge.Cells.Count

Oder in einem Befehl:

MsgBox Application.Intersect(Range(Cells(Range("B2").Value2, 1), Cells(Range("B3").Value2, 1)), Range(Cells(Range("B5").Value2, 1), Cells(Range("B6").Value2, 1))).Cells.Count

Klappt! Danke an Andreas Protzmann für diesen Hinweis. Auch clever!

Und schließlich reagiert Christian:

Auch sehr clever! Und sehr elegant! Danke, Christian.

Heute habe ich gelesen, was auf der Flasche Shampoo steht: Für extra Volumen und mehr Fülle!!! Kein Wunder, dass es mir schwerfällt, mein Gewicht zu kontrollieren! Ich werde ab sofort Geschirrspülmittel benutzen! Da steht drauf: entfernt auch hartnäckiges Fett.

Einfach nicht aufgepasst!

Mit VBA wird eine Userform (eine Maske) erstellt zur bequemen Dateneingabe. Der Wert eines Textfeldes wird als String interpretiert und als solcher bei Dezimalzahlen in eine Excelliste eingetragen. Man erkennt es, weil die Zahlen linksbündig in der Zelle stehen:

Dummerweise wird ein Text immer größer als eine Zahl definiert, so dass eine Formel

=WENN(J2>1000;WAHR;FALSCH)

immer WAHR liefert!

Intelligente Überschriften zu schreiben, ist gar nicht so einfach. Schon ein einziger Buchstabendreher kann den ganzen Inhalt urinieren.

… und ich kann es nicht lassen, zu mailen, mit den Infos:

  • aktuelle Formel (Konstrukt von gestern), wo noch etwas fehlt:
    =WENN(ANZAHL(J9;L9;N9)=0;““; WENN(ODER(ANZAHL(J9;L9;N9)=2;ANZAHL(J9;L9;N9)=3); MITTELWERT(J9;L9;N9); „“))
  • drei Eingabezellen
  • wenn keine Eingaben in den Zellen >> Zelle mit Ergebnis ist leer
  • der MW wird berechnet, wenn zwei oder drei Zellen Werte enthalten

Frage: Kann man noch prüfen
wenn ODER(Prüfung auf TEXT(J9), Prüfung auf TEXT(L9), Prüfung auf TEXT(N9)): „“
D.h.: Wenn mindestens eine der Zellen Text beinhaltet >>> Ergebnis der Zelle: Nix drinnen
Ich habe schon ein wenig schlechtes Gewissen …
Ich maile noch ein DANKESCHÖN & Gruß
Jürgen

Hallo Jürgen,

deine Bedingungen werden mit

=WENNFEHLER(WENN(ANZAHL(J9;L9;N9)>1;MITTELWERT(J9;L9;N9);"");"")

abgefangen. Die Funktion MITTELWERT übergeht (ebenso wie SUMME, ANZAHL, MAX, …) Texte. Senn du das explizit abfangen willst, dann beispielsweise so:

=WENNFEHLER(WENN(ANZAHL(J9;L9;N9)<ANZAHL2(J9;L9;N9);"";WENN(ANZAHL(J9;L9;N9)>1;MITTELWERT(J9;L9;N9);""));"")

Liebe Grüße

Rene

Ich achte auf meine Ernährung: Was schmeckt, wird gegessen.

Excelschulung. Eine junge Teilnehmerin. Azubi.

Sie zeigt mir Beispiele von ihrem Lehrer, die sie verstehen und können muss, da ähnliche Beispiele Teile der Prüfung von Excel sind. Geübt werden sollen einige Formeln:

Der prozentuale Anteil wird berechnet:

=WENN(UND(A15<>"";B15<>"");D15*100/$D$25;"")

Okay, mit der Funktion

UND(A15<>"";B15<>"")

wird überprüft, ob die Zellen der Spalte A und B gefüllt sind. Eine hübsche Übung, um UND und WENN zu üben.

Dennoch: WENNFEHLER wäre sicherlich besser gewesen, um ALLE Fehler abzufangen.

Aber noch mehr irritiert mich die Berechnung

D15*100/$D$25

Warum wird mit 100 multipliziert? Ich hätte den Anteil von einer Dezimalzahl in eine Prozentzahl formatiert. Und damit weitergerechnet.

Wäre das nicht eher im Sinne von Excel gewesen?

Entweder finden Jogger Leichen oder sie werden selbst ermordet. – Was soll daran gesund sein?

Excelschulung. EIne junge Teilnehmerin. Azubi.

Sie zeigt mir Beispiele von ihrem Lehrer, die sie verstehen und können muss, da ähnliche Beispiele Teile der Prüfung von Excel sind. Geübt werden sollen WENN und SVERWEIS:

Ich sehe folgende Formel:

=WENN(A17="";"";SVERWEIS(A17;Leistung;2))

Ist ja okay zu überprüfen, ob A17 leer ist, aber wäre es nicht besser ALLE Fehler mit einem WENNFEHLER abzufangen?

Sicherlich dient diese Formel WENN zum Üben …

En Dios creemos; todos los demás deben mostrar datos.*)

Hallo Herr Martin,

mein Bekannter hat sich die neue Version angeschaut.

Jetzt lässt sich der Datensatz zwar anlegen, aber es treten neue Fehler auf, die bisher noch nicht vorhanden waren.

In der Tabelle erscheint nach dem Löschen des Datensatzes ein Fehler.

Hallo Herr L.,

öffnen Sie mal bitte eine ältere Version und klicken Sie dort auf Datenverwaltung und löschen Sie einen Datensatz.

Klicken Sie anschließend auf den Datensatz direkt über dem Datensatz, den Sie gelöscht haben.

Sie erhalten den Fehler.

Heißt: DIESER Fehler war schon lange drin, bevor Sie mir die Datei geschickt haben.

Woher kommt er?

Beim Löschen einer Zeile liefert die Zeile darüber einen Fehler:

Sie greifen auf den VALUE dieser Zelle zu – das knallt!

Die Ursache des Fehlers:

In der Spalte K (Membership) greift die Formel für den Wert „Silber“ auf die Zeile darunter zu! Die Formeln dieser Spalte sind falsch! Schon bevor Sie mir die Datei geschickt haben!

=WENN(UND(H2="Spain";J2>200);"Black";WENN(UND(H2="Spain";J2>180);"Platinum";WENN(UND(H2="Spain";J2>150);"Gold";WENN(UND(H3="Spain";J2>140);"Silber";WENN(UND(H2="Spain";J2>130);"Standard";WENN(UND(H2="Spain";J2>50);"Blue";"out of order"))))))

Fazit: es sind nicht neue Fehler – in Ihrem Programm sind einige alte Fehler, für die ich mich nicht verantwortlich zeichne.

An dieser Maske dlgKundenverwaltung habe ich nichts geändert.

schöne Grüße

Rene Martin

*) An Gott glauben wir; alle anderen müssen Daten zeigen!

Alexa, wie verhindere ich, dass meine Daten ins Internet kommen?

Hallo, ich habe auch so ein Problem in meinem Kalender zur Arbeitszeitberechnung mit den Rauten. Excel gibt mir aber den Hinweis, das entweder die Zelle zu klein ist, oder ein Negativ Wert darin enthalten ist. Bei mir scheint es wohl der Negativ Wert zu sein da eine Formel in der Zelle enthalten ist bei der ich zb. 8 von 9 in meinem Fall Stunden abziehen möchte. Da ich die Zeiten über Dropdown Listen eingebe, habe Rauten in den Zellen solange ich noch keine Werte eingegeben habe. Das sieht natürlich nicht so gut aus. Nun meine Frage. Kann man diese Rauten auch einfach nur ausblenden ohne das die darin enthaltenen Formeln auch ausgeblendet sind? Ich hoffe das ich mein Problem verständlich erklären konnte.

Gruß Uli.

Hallo Uli?

Ich würde um die Formel (wie sieht sie aus?) beispielsweise
=C2-B2
eine WENN-Funktion bauen:

=WENN(C2-B2<0;““;C2-B2)

Hilft das?

Liebe Grüße

René Martin

Hallo Herr Dr.Martin,

Danke Ihnen nochmal für ihre Hilfe, es hat geklappt mit der Formel.

War für Sie bestimmt eine Logische und einfache Sache, aber für mich als Blutiger Anfänger ein Riesen Problem. Würde mich freuen wenn ich mal wieder so ein Problem hätte, mich an Sie wenden dürfte.

Mit freundlichen Grüßen U.

Klar, Uli,

einfach schreiben! Ich helfe gerne

Liebe Grüße aus dem verregneten München

Rene Martin

PS: ich mag den Begriff „logisch“ nicht. Es läuft eine gewisse erlernbare Mechanik ab. Jeder von uns hat ein bestimmtes Wissen und erkennt Lösungen „intuitiv“ und kann sie sicherlich auch beschreiben, warum dieser oder jeder Weg der richtige (oder der geeignete) ist. Also: Kopf hoch, dranbleiben, schmunzeln – ich halte Excel für wichtig – nicht, weil ich häufig damit arbeite, sondern weil sehr, sehr viele Menschen häufig damit arbeiten.

Es ist gut, dass nicht jeder ein Smartphone hat. Wir brauchen Menschen, die hupen, wenn es grün wird.

Hallo Herr Martin,

ich habe eine Art Kalender, also beginnend mit dem 01.01.2018, endend mit
dem 31.12.2018.
Bei der Aufziehung des Datums lasse ich das Wochenende weg.
In einer Extra-Spalte soll vor jedem Montag die Kalenderwochenzahl stehen.
Wenn ich diese Funktion anwende, wird die Kalenderwochenzahl auch vor den
Tagen Dienstag bis Freitag eingefügt.
Gibt es eine Möglichkeit, z. B. über die Bedingte Formatierung, daß die
Kalenderwochenzahl nur neben dem Montag gezeigt wird?
Herzliche Grüße

####

Hallo Herr F.,
ich würde es mit einer WENN-Funktion lösen. Beispielsweise so (wenn in B1) das Datum steht:
=WENN(WOCHENTAG(B1;2)=1;ISOKALENDERWOCHE(B1);„“)
schöne Grüße
Rene Martin

####

Hallo Herr Martin,

das ging aber recht schnell mit Ihrer Antwort. Vielen Dank.

Ich habe etwas herum experimentiert und diese Lösung benutzt.

Einzig beim Übergang von 2018 zu 2019 scheint dies nicht zu funktionieren, denn der 31.12.2018 ist zwar noch zum alten Jahr gehörig, müßte aber dennoch mit der 1 beginnen, macht es aber nicht:

Herzliche Grüße

####

Hallo Herr F.,
ich bin nicht sicher, ob in Excel 2010 bereits der Parameter 21 in der Funktion KALENDERWOCHE vorhanden war. Schauen Sie mal bitte nach – ich habe hier kein Excel 2010. Wenn das nicht der Fall ist, müssen Sie die Funktion ISOKALENDERWOCHE nachbauen. Anleitungen finden Sie im Internet.
schöne Grüße
Rene Martin

####

Hallo Herr Martin,
vielen Dank für Ihre letzte Antwort. Sie haben natürlich recht: mit ISOKALENDERWOCHE läßt sich das Problem beheben.
Wie ist es aber, wenn man Excel 2010 benutzt. Da gibt es diese Funktion nicht. Wie ließe ich hier das Problem lösen, also nur daß vor dem Montag die Kalenderwochenzahl steht?
Herzliche Grüße

####

Hallo Herr Martin,

den Parameter 21 hat Excel 2010 nicht.

Mal sehen, was ich im Internet finde, bisher habe ich nichts gefunden.

Dennoch vielen Dank.

Herzliche Grüße

####

Hallo Herr Martin,

ich muß mich korrigieren. Der Parameter 21 ist in Excel 2010 vorhanden.

Ich habe wie folgt die Funktion geschrieben:

=WENN(WOCHENTAG(B1;2)=1;KALENDERWOCHE(C1;21);„“)

Und es funktioniert auch der Wechsel von der 52. KW 2018 zur KW 1 2019.

Herzliche Grüße

####

Wer nervt mehr? Excel oder Menschen?

Meditieren ist immer noch besser, als rumsitzen und nichts tun.

Heute in der Excelschulung. Ich zeige den Teilnehmer das „Leerzeichenproblem“: Manchmal geben Anwender und Anwenderinnen am Ende eines Textes Leerzeichen ein, das man nicht sichtbar machen kann. Das ist fatal beim Sortieren, bei Pivottabellen, die Funktionen WENN, ZÄHLENWENN, SUMMEWENN rechnen vermeintlich falsch … Man kann solche Leerzeichen mit der Funktion RECHTS ausfindig machen, man kann sie mit GLÄTTEN entfernen, … All das zeige ich. Weise darauf hin, dass man (zugegeben: sehr schlecht!) die Leerzeichen sichtbar machen kann, wenn man die Texte rechtsbündig formatiert:

Eine Teilnehmerin meldet sich und fragt, warum bei ihr die Texte am Ende KEINE Lücke aufweisen, obwohl sie ein Leerzeichen eingefügt hat:

Die Antwort: Wenn am Ende eines Textes sich ein Leerzeichen befindet, wird es unterdrückt, wenn ein Textumbruch eingeschaltet ist !?!

Ich weiß, du hast recht – aber meine Meinung gefällt mir besser.

Hallo Herr Martin,

ich befinde mich derzeit in einem Excel-Grundkurs und bin bei einer „verschachtelten Wenn-Funktion“ auf folgende Problematik gestoßen:
Excel rechnet nicht weiter, sobald der erste „Wahr“wert erreicht ist, was zu logischen Fehlern führt, sofern die Abfragewerte aufsteigend abgefragt werden.
Der „Sonst“Wert wird allerdings korrekt ausgegeben.
In meinem Beispiel habe ich dann die Abfragewerte 25% und 20% umgekehrt und es hat wie geplant funktioniert.
Wo liegt mein Fehler?
Haben Sie eventuell eine Idee zur Vereinfachung der Funktion?
Im voraus vielen Dank für Ihre Hilfe.
Mit freundlichen Grüßen
Jan

Hallo Herr S.,

Sie haben recht: Excel arbeitet Wenn-Funktionen baumartig ab. Also:

Wenn > 80% dann

wenn > 75% dann

sonst: Rest <= 75%

Sie können es aber auch „umbauen“:

wenn <= 75% dann

wenn <= 80% dann

Rest: sonst > 80%

Tipp: ich zeichne manchmal so eine Baumstruktur auf, um es besser zu verstehen.

Tipp 2: schreiben Sie 2 und 5 und nicht „2“ oder „5“. Sie möchten ja mit dem Zahle weiterrechnen. Sie können übrigens auch 2% und 5% verwenden

Hallo Herr Martin,

vielen dank für die schnelle Antwort.

Das ganze ist ja ganz schön verwirrend, gibt es dann noch eine andere Funktion die das Ziel einfacher erreicht?

Schöne Grüße

Jan

Hallo Herr S.

schauen Sie sich einmal die Funktion SVWEIS an – dort werden mehrere Fälle auf einer Ebene abgearbeitet.

Das Universum spielt nicht immer fair, aber dafür hat es einen höllischen Sinn für Humor

Hallo René,

und hier sende ich Dir die Datei mit meinen Hinweisen.
Aber warum nimmt Excel die neuen Zielumsätze (denen kein Umsatz vorausgegangen war) nicht ins Gesamtergebnis auf?
Ich berechne: Zielumsatz = WENN(Umsatz>0;Umsatz*110%;500)
Viele Grüße
Angelika

Hallo Angelika,

Ich weiß wo der Denkfehler – oder der Pivotfehler steckt:

Pivot rechet nicht Summe der einzelnen berechneten Werte, sondern: berechnet die Summe:

Also nicht (in deinem Beispiel 3.045,90 + 500,00 + 594,83 + 2.692,80), die ja berechnet sind: = WENN(Umsatz>0;Umsatz*110%;500)

sondern Pivot rechnet: 2.769,00 + 0,00 + 540,75 + 2.448,00. Wenn diese Summe (5.757,75) > 0;Umsatz*110%;500) -> also 5.757,75 + 1,1 = 6.333,53

Nervt Excel?

Liebe Grüße  ::  Rene

 

Aus Langeweile hätte ich eben fast gearbeitet. Man muss aber auch höllisch aufpassen.

Gestern in der Excel-Schulung. Wir üben die WENN-Funktion. Standard-Beispiel: eine Provisionsberechnung. Ein Teilnehmer ruft mich, weil er eine Fehlermeldung erhält:

Ich gestehe: ich habe drei Mal hinschauen müssen, bis ich es entdeckt hatte: das schließende Anführungszeichen bei dem Sonst-Zweig (Wert_wenn_falsch) fehlt.

Denken ist wie googeln – nur krasser.

Amüsiert war ich schon. In einer Firma sollte ich letzte Woche Excel-Formeln anpassen. Man erklärte mir, dass jeder Auditvorgang ein Revisionsdatum hat. Möglicherweise auch ein zweites und ein drittes. Wenn es ein drittes Datum gibt, gibt es auch ein zweites. Also: die Tabelle ist gefüllt: entweder 1. Datum oder 1. und 2. oder 1. und 2. und 3. oder alle vier Spalten sind mit einer Datumsinformation gefüllt.

20170129Anzahl

Ein Kollege hatte eine Formel erstellt:

=WENN(H2=““;1;WENN(I2=““;2;WENN(J2=““;3;4)))

Meine Aufgabe war es diese Formel für weitere Datumsangaben anzupassen. Ich war etwas irritiert.

=ANZAHL(G2:J2)

hätte das Gleiche getan. Und ist leichter anzupassen. Die Teilnehmer waren begeistert und glücklich.

Excel hält sich nicht an die Theoreme der Prädikatenlogik

Kennen Sie das: Ich benötige eine Liste, die sich dynamisch fortsetzt. In einer Zelle wird ein Wert eingetragen – die Nummer eines Zählers soll nur bis nur eingetragenen Nummer angezeigt werden.

Die Formel:

=WENN(A9=$B$4;A9+1;““)

funktioniert problemlos –

=WENN(A9=$B$4;““;A9+1)

jedoch nicht.

Einer geht und einer nicht.

Einer geht und einer nicht.

20160626weiter01

Der Grund ist offensichtlich. Befindet sich in einer Zelle ein leerer String („“), kann Excel zwar problemlos den Ausdruck

12 = „“

auswerte und FALSCH zurückgeben. Jedoch bei den Operatoren der Ungleichheit (<, >, <= und >=):

12 < „“

liefert Excel einen Fehler. Also aufpassen: man darf nicht immer einfach rumdrehen!

Wenn das Wörtchen WENN nicht wär‘ …

Sehr geehrter Herr Dr. Martin,

Wahrscheinlich haben Sie wesentlich schneller eine Lösung parat als ich, die ich nun schon stundenlang damit rummache und jetzt irgendwie aufgebe.

Es geht um dieselbe Tabelle, also diese Zeitberechnung.

Nun soll aber noch folgendes dazu berechnet werden.

Wenn die Stundenanzahl >= 6 Stunden sollen 0,5 Stunden abgezogen werden, wenn die Stundenanzahl >= 10 Stunden soll eine Stunde abgezogen werden.

Ich habe versucht, mich langsam heran zu tasten und habe sogar die > 6 Stunden und >10 Stunden einzeln herausbekommen. Allerdings bekomme ich nun beim besten Willen diese ganzen Schachteln nicht zusammengesetzt…(Das mit dem „=“ dazu hat auch nicht so funktioniert…)

Haben Sie eine (schnelle) Lösung oder eine passende Erklärung mit einem Link?

Die Tabelle mit meinen Versuchen ist angehängt. Wie ich gelesen hatte, muss man dazu die Uhrzeit wieder in eine normale Zahl formatieren, was ich getan habe.

Herzlichen Dank für Ihre Bemühungen.

####

Stundenberechnung

Stundenberechnung

Hallo Frau P.,

Ich denke, Ihr Problem resultiert aus Folgendem: Sie sollten sich einen Baum malen, der die verschiedenen Fälle auflistet: tagsüber gearbeitet oder nachts? In beiden Fälle: mehr als 10 Stunden – > ja: eine Stunde abziehen. Nein: – > wenn mehr als sechs Stunden: -> ja, 0,5 Stunden abziehen – sonst nichts.

Und so müssen Sie die Formel eingeben.

Kommen Sie damit klar?

####

Hallo Herr Dr. Martin,

Jetzt habe ich gesehen, dass Sie die Sachen ja alle schon richtig ausgefüllt haben.

Das Resultat ist in „Zahl“ formatiert. Ich glaube, es wäre auch mit der „Uhrzeit 37:…“ gegangen. Allerdings nicht mehr in dieser Version.

Ich kann es nur hinnehmen und Ihnen danken, dass Sie es eingerichtet haben. Vom Verständnis bin ich leider noch etliches entfernt.

Aber ich denke, meine Kolleginnen werden sich freuen, endlich eine funktionierende Zeitberechnung zu haben. Bleibt zu hoffen, dass ihnen nicht noch etwas Neues einfällt…

Also noch einmal: Herzlichen Dank!

Ich wünsche Ihnen noch einen schönen Tag.

####

Gerne, Frau Pojer,

wenn Sie es verstehen möchten, machen Sie Folgendes:

Klicken Sie auf eine Zelle mit einer Formel. Klicken Sie auf den Funktionsassistenten.

Sie sehen die Bedingung. Klicken Sie nun in die Bearbeitungszeile auf den Teil den Sie sehen möchten. So können Sie sich den Baum entlanghangeln:

Der Funktionsassistent

Der Funktionsassistent

Umgekehrt: gehen Sie an ein solches Problem mit einem Blatt Papier und einem Stift ran. Ich „mal gerne Bäume“. Sicherlich kennen Sie diese Ablaufdiagramme: sie helfen:

Ein kleines Diagramm - als Hilfe

Ein kleines Diagramm – als Hilfe

Da fehlt doch was!

Ein Kollege von mir hat mir eine Formel in Excel erstellt. Ich verstehe die Formel aber nicht. Im dritten WENN-Teil fehlt doch ein Teil, oder?

Fehlt da nicht etwas?

Fehlt da nicht etwas?

Die Antwort: Schauen wir uns die Formel mal genauer an:

=WENN(AJ2=““;““;WENN((AJ2)>14;“zu lang“;WENN(AJ2<=14;“ok“;)))

Der erste Teil ist klar (=WENN(AJ2=““;““): Wenn die Zelle AJ2 leer ist, dann bleibe ich selbst auch leer. Prima.

Im zweiten Teil wird überprüft, ob in AJ2 ein Wert größer als 14 steht:

WENN((AJ2)>14;“zu lang“

Wenn das erfüllt ist, so liefert die Formel den Text „zu lang“. Nun wollte der Kollege überprüfen, ob der Wert kleiner oder gleich 14 ist. Er hat dies mit einer weiteren WENN-Funktion realisiert. Das ist nicht falsch, aber überflüssig.

Ich würde die Formel folgendermaßen schreiben:

=WENN(AJ2=““;““;WENN((AJ2)>14;“zu lang“;“ok“))

Sie liefert das gleiche Ergebnis und ist viel kürzer.

So geht es auch - das ist sogar eleganter!

So geht es auch – das ist sogar eleganter!